Programming samples by Robert Elton Maas <rem@BTR.Com>
HyperTalk (scripting language inside HyperCard)


These are excerpts from Database.HC, program to plot gasoline usage
against miles driven:

Script of button "Plot":
on mouseUp
  put 100 into lox
  put 300 into hix
  put hix-lox into delx
  put 330 into loy
  put 200 into hiy
  put hiy-loy into dely
  choose rectangle tool
  drag from lox,loy to hix,hiy
  choose brush tool
  put card field "ododel" into totmil
  put card field "totgal" into totgal
  put card field "CarMil input data" into dat
  put card field "Nrows" into nr
  put odometer(line 1 of dat) into odo0
  put 0 into galsofar
  repeat with ix = 2 to nr
    put line ix of dat into lin
    if (the number of words in lin) <> 7 then
      answer (the number of words in lin)&"//"&lin
      answer (word 2 of lin)&"//"&(word 3 of lin)
    end if
    put odometer(lin) into odo
    put fullnf(lin) into fnf
    put (number of characters in odo) into odolen
    if (char odolen of odo) is not "?" then put odo-odo0 into milesofar
    add gals(lin) to galsofar
    put (milesofar/totmil)*dely + loy into y
    put (galsofar/totgal)*delx + lox into x
    if ((char odolen of odo) is not "?") and (fnf is "FULL") then
      --answer odo
      click at round(x),round(y)
    end if
  end repeat
  choose browse tool
end mouseUp


Excerpts from FileStuff, utility to browse a list of files and create a
description record for each:

Script of button "Load Filenames":
on mouseUp
  put card field "FNFN" into fn
  open file fn
  read from file fn for 20000
  put it into card field "Filenames"
  close file fn
  put 1 into card field "FNIX"
  put number of words in card field "Filenames" into card field "FNIZ"
  select word 1 of card field "Filenames"
end mouseUp

Script of button "Next":
on mouseUp
  get MayClose()
  put card field "FNIX" into ix
  put card field "FNIZ" into iz
  if ix<iz then
    put ix+1 into ix
    put ix into card field "FNIX"
    put "" into card field "MainBuf"
    put "" into card field "BufNch"
  else
    answer "That was the last file name"
  end if
  select word ix of card field "Filenames"
end mouseUp